
It can be useful to detect the end of the data when processing a SAS data set or when you are inputting data into SAS from a flat file.  You might want to summarize some data you have been collecting as the data is processed, or maybe you would like to add some extra observations to the file.  For instance, if you plan to run a regression analysis, you may want to add some specific values of the independent variables to the dataset so that you can get PROC REG to output the predicted values with confidence limits. 

There are three different possibilities.  The data:

1) is already in a SAS data set; or it

2) is in a flat ASCII file which will be referred to with an INFILE statement; or it

3) is included in the program using the CARDS or DATALINES statement.

As an example, we will consider doing a regression analysis of y on x1 and x2.  Suppose we want to get PROC REG to calculate predicted values for x1 and x2 values of interest.  If we add those values to the SAS data set the PROC REG will do that automatically.  But the response variable, y, must be given missing values for these added data points so that they will not influence the fit of the regression (otherwise they may be given the y-value of the last observation in the data!).

Example 1: Data already in a SAS data set.

Suppose that the data we want to use is already in a SAS data set called regfit.  Then we simply need to start a new data step and use the END data set option to create a variable, last, to identify the end of the data.  This variable will have a value of zero (0) for most of the observations except for the last observation where it will be given a value of one (1).

The new dataset regfit will replace the old one.  To ensure that every observation in the old dataset is output to the new dataset we need to add an OUTPUT statement.  This is because we will be using another OUTPUT statement later in the data step that works just for the new observations and not the old ones. 

data regfit; 

  set regfit end=last; 

  output;

Now we use the end variable that we called last. When last = 1 the following statements will be executed.   The following statements then create a combination of x1 and x2 values with missing values for y.  Each combination is output into the data set as a new observation.  All of these observations are added to the end of the dataset.  If necessary, these could be resorted with a PROC SORT procedure following the data step. 

  if last then do x1 = 9 to 21 by 3; 

       do x2 = 12 to 15 by 1; 

         y = .;   output; 

  end; end;

  label y = 'Y-variable'  x1 = 'First X-var' x2 = '2nd X-var';

run;
Note that we could also have written: if last = 1 then ... instead of just if last then ....

Example 2: Data in an external flat ASCII file.

When reading the data in from an external flat ASCII file we replace the SET statement with an INFILE statement.  Otherwise the procedure is very similar to Example 1.

The INFILE statement tells SAS to look for the data in the file ‘example data.txt’ that is within the current working directory (this directory is listed at the bottom of the SAS windows).  The option, end=last, creates a variable called last which, as before, will have a value of zero (0) for most of the observations except for the last observation where it will be given a value of one (1).

Next the data is read in using the input statement and, again, we need to add an OUTPUT statement to ensure that each observation read in is included in the new SAS data set.

title 'Regression Analysis: adding x-values to get predicted values';

data regfit;

  infile 'example data.txt' end=last;

  input y x1 x2;

  output;

Now we use the end variable, last, using the same code as in Example 1.

 if last then do x1 = 9 to 21 by 3; 

        do x2 = 12 to 15 by 1; 

          y = .;   output; 

     end; end;

  label y = 'Y-variable'  x1 = 'First X-var' x2 = '2nd X-var';

run;

Example 3: Data included in the program code.

If the data are included as part of the data step programming then the end option is no longer available.  Instead, we can create a statement label with the EOF option (EOF = end of file) of the INFILE statement.  This statement label specifies a location for an implicit GO TO statement when the INFILE statement reaches the end of the file.  SAS will move processing to the statement label when the INPUT statement reaches the end of the input file.

The first part of the data step looks much the same as before.  The DATALINES or CARDS specification within the INFILE statement specifies that the data is located within the program after a DATALINES or CARDS statement (the end of the data is indicated by the presence of a  ‘;’ in the line just after the data).  Further, last will be the statement label to GOTO when the end of the data has been reached.

Besides including an OUTPUT statement as before, we now need to add a RETURN statement so that SAS will ignore the code following it and begin again at the beginning of the data step when reading in the next observation.

title 'Regression Analysis: adding x-values to get predicted values';

data regfit;

  infile datalines eof=last;

  input y x1 x2;

  output; return;

After the last observation is read in SAS looks for a statement label called last. The SAS code following that label is then processed.  The following code is very similar to that in the previous examples except that we don’t have an IF … THEN statement now, but a statement label instead.

last: do x1 = 9 to 21 by 3; 

       do x2 = 12 to 15 by 1; 

         y = .;   output; 

     end; end;

  label y = 'Y-variable'  x1 = 'First X-var' x2 = '2nd X-var';

datalines;

 46.4    15.3    12.91

 43.2    15.0    13.20

 49.4    14.1    12.66

 49.2    14.4    12.37

 47.3    15.3    13.15

       .

       .

       .

 47.0    12.6    13.75

 50.0    12.3    12.45

 48.2    17.1    12.87

 50.6    17.4    12.20

 46.1    15.9    12.75

run;
Note that this approach of using the statement labels created from the EOF= option of the INFILE statement could also have been used for example 2 with the data stored in an external flat ASCII file. 

Any of these approaches will have added the necessary observations for you to now proceed with the multiple regression analysis and obtain predicted values for desired values of the independent variables as part of the output.
















� This material is provided for informational purposes only; no guarantees are implied.

